Claude's Corner: Art Works

Yes, 3D art works too

It's been a few years, but as of December 2021 I'm back on my bullshit:

The idea was to recreate an old drawing, but it didn't work out, and now I'm not sure what to add to make it less empty.

Anyway, here's the source code:

// Persistence of Vision Ray Tracer Scene Description File
// File: happy-rocketship.pov
// Vers: 1
// Desc: A happy rocketship!
// Date: 2021-12-07
// Auth: Claude LeChat <https://nosycat.neocities.org/>

#version 3.7;

#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"

global_settings { assumed_gamma 1.0 }

camera {
	location <0, 0, -1>
	look_at <0, 0, 0>
	// angle 48
}

light_source { <0, 0, -99> color White /*rotate <-30, -15, 0>*/ }

sphere {
	<0, 0, 3>, 1
	pigment { Brown_Agate scale 3 }
	rotate <0, -30, 30>
}

// Fake color nebula
#declare Nebula_Size = 5;

sphere {
	<0, 0, 5>, Nebula_Size
	pigment { rgbf <1, 1, 1, 1> }
	hollow interior {
		media {
			emission 0.3
			density {
				agate
				color_map {
					[0.0 NewMidnightBlue]
					[0.05 Black]
					[0.95 Black]
					[1.0 DarkPurple]
				}
			}
			scale Nebula_Size
		}
	}
	//rotate <0, -15, -45>
}

// Rocketship
union {
	difference {
		sphere {
			<0, 0, 0>, 0.5
			scale <0.89, 0.13, 0.13>
		}
		cylinder {
			<0, 0, -0.07>, <0, 0, 0.07>, 0.02
			translate x * 0.1
		}
		cylinder {
			<0, 0, -0.07>, <0, 0, 0.07>, 0.02
			translate x * 0.2
		}
		cylinder {
			<0, 0, -0.07>, <0, 0, 0.07>, 0.02
			translate x * 0.3
		}
	}
	
	cylinder {
		<0, 0, -0.07>, <0, 0, 0.07>, 0.02
		texture { Dark_Green_Glass }
		translate x * 0.1
	}
	cylinder {
		<0, 0, -0.06>, <0, 0, 0.06>, 0.02
		texture { Dark_Green_Glass }
		translate x * 0.2
	}
	cylinder {
		<0, 0, -0.05>, <0, 0, 0.05>, 0.02
		texture { Dark_Green_Glass }
		translate x * 0.3
	}
	
	// Engine nozzle
	cone {
		<-0.45, 0, 0>, 0.03, <-0.4, 0, 0>, 0
	}

	// Tail fins
	cone {
		<-0.3, 0, 0>, 0.1, <-0.35, 0.15, 0>, 0.05
		scale <1, 1, 0.1>
	}
	cone {
		<-0.3, 0, 0>, 0.1, <-0.35, 0.15, 0>, 0.05
		scale <1, 1, 0.1>
		rotate x * 120
	}
	cone {
		<-0.3, 0, 0>, 0.1, <-0.35, 0.15, 0>, 0.05
		scale <1, 1, 0.1>
		rotate x * -120
	}
	
	texture { T_Chrome_2A }
	
	rotate <15, 30, 15>
}